[Un ringraziamento a Massimo Stella e a Leonardo Boselli che sono due «fighi allucinanti» senza "se" e senza "ma".]
Include Italian Language by Massimo Stella.
The story description is "Memorie di uno studente è una Interactive Fiction intrigante: ogni riferimento a fatti realmente accaduti e/o a persone realmente esistenti è da ritenersi puramente intenzionale. Questo non è un disclaimer ma bensì la descrizione stessa di questa storia. Che non vede l'ora di essere vissuta."
The story headline is "Una Interactive Fiction".
The story genre is "Diario".
The story creation year is 2014.
The release number is 0.
Part 2 - Definizioni
[Understandi]
Understand "sali [something]" or "sali sulla/sulle/sul/le/la [something]" as entering.
Understand "analizza [something]" or "analizza il/la/lo/i/le/gli/l/quei/quella/quello/quelle/quegli/quei/quell [something]" as examining.
Understand "distruggi [something]" or "distruggi il/la/lo/i/le/gli/l/quei/quella/quello/quelle/quegli/quei/quell [something]" as attacking.
Understand "posa [something]" or "posa il/la/lo/i/le/gli/l/quei/quella/quello/quelle/quegli/quei/quell [something]" as dropping.
Understand "straccia [something]" or "straccia il/la/lo/i/le/gli/l/quei/quella/quello/quelle/quegli/quei/quell [something]" as cutting.
Understand "strappa [something]" or "strappa il/la/lo/i/le/gli/l/quei/quella/quello/quelle/quegli/quei/quell [something]" as cutting.
Understand "stampa [something]" or "stampa il/la/lo/i/le/gli/l/quei/quella/quello/quelle/quegli/quei/quell [something]" as stampare.
Stampare is an action applying to one thing.
[Soppressione frasi stupide]
The can't go through closed doors rule does nothing.
[Arricchimenti]
A door can be either accessibile or inaccessibile.
[Scala]
A scala is a kind of door. A scala is usually open. A scala is seldom openable.
[Nastro]
A nastro is a kind of thing. A nastro can be either intatto or tagliato. A nastro is usually intatto.
[Ascensore]
A ascensore is a kind of door. A ascensore is usually open.
Before going to a room:
Let place be the door gone through;
if place is an ascensore:
say "[italic type][The place] si apre e ti porta velocemente [dap the room gone from] [ap the room gone to]. [The place] si richiude immediatamente alle tue spalle.[roman type][paragraph break]".
[Porta a tentativi]
A porta a tentativi is a kind of door. It is lockable and locked. It has a number called tentativi. Tentativi is usually 3.
Instead opening locked a porta a tentativi:
if the tentativi of noun is 0:
end the story saying "È scattato l'allarme e il custode si è svegliato.";
otherwise:
let numero a caso be a random number between 1000 and 9999;
say "[The noun] è ora bloccata, ma si può provare a forzarla. Proviamo con un codice a caso: [numero a caso]![paragraph break][italic type]* Bip bip bip bip! *[line break][italic type]* AUTH ERROR: ONLY [tentativi] ATTEMPTS LEFT *[roman type][paragraph break]È andata male.";
Now tentativi of noun is tentativi - 1.
A porta murata is kind of door. A porta murata is feminine gender closed unopenable locked.
[Stampante (TODO BETTER)]
A tessera fotocopie is a kind of thing.
A stampante is a kind of device. It is usually switched on.
Before stampare a thing when thing is a stampante:
if player carry a tessera fotocopie:
say "[if noun is switched on]È stata fatta una fotocopia del mio sedere. Eheheh..[otherwise]Sarà difficile: Pare che [the noun] non sia accesa.[end if]";
otherwise:
say "Servirebbe una tessera fotocopie.".
[Script per indicare TUTTE le direzioni POSSIBILI (prima porte, poi stanze) (TODO BETTER)]
After looking:
say "Direzioni: ";
repeat with way running through directions:
let place be the room way from the location;
let porticina be the door way from the location;
if porticina is a door:
say "[bold type][way][roman type] per [italic type][porticina][roman type]. ";
else if place is room:
say "[bold type][way][roman type] per [italic type][place][roman type]. ".
[Rivelatore di cose nascoste in un container o un supporter]
After examining an object:
let oggetto contenitore be noun;
if oggetto contenitore is a container:
Repeat with item running through every undescribed thing in oggetto contenitore:
say "Ti salta all'occhio [a item].";
Now item is described;
else if oggetto contenitore is a supporter:
Repeat with item running through every undescribed thing on oggetto contenitore:
say "Ti salta all'occhio [a item].";
Now item is described.
Part 3 - Preambolo
The mini torcia is a lit feminine gender device. Mini torcia is switched on. The description is "La mia sacra [mini torcia] elettrica.". Before switching on mini torcia: Now mini torcia is lit. Before switching off mini torcia: Now mini torcia is unlit. After switching on mini torcia when player is in a dark room: say "La stanza fa meno paura adesso...".
biscotti are a plural-named edible thing. The description is "Quel tipo di 'genere di conforto' che fa sempre piacere.".
The player carry a mini torcia and biscotti.
When play begins: say "...[paragraph break]Dal Diario personale - 28 maggio (23:30)[line break][italic type]La quinta superiore è arrivata per me un po['] troppo velocemente. Mi sono ritrovato all[']improvviso con 6 materie sotto. Proprio quest[']oggi i miei hanno ritrovato la lettera. Esatto.. Quella che era stata mandata dalla scuola e che io avevo a buon ragione nascosto temendo lo sgridone.. Morale? Ora mio padre sta mandando all[']aria la mia vacanza con i miei amici. Ho perso tutto.. ho perso un anno scolastico, ho perso il mio viaggio e con esso ho perso l[']unica occasione di rivederla...[paragraph break][roman type]Dal Diario personale - 28 maggio (03:02)[line break][italic type]Ho un piano.[roman type][paragraph break]...".
Part 4 - Corridoio presidenza (Ufficio del Preside e Presidenza)
Presidenza is a feminine gender room. The description is "La tana del lupo.".
The cassetti docenti are backdrops in Presidenza.
The stampante MFP is a feminine gender stampante in Presidenza.
Ufficio del Preside is a room. The description is "È una bellissima saletta con una grande vetrata che dà sul giardino, però qui è tutto in disordine. Premi e foto sono appese sulle pareti e vi è [the libreria] piuttosto allegra. Probabilmente il Preside usa [a porta blindata] per non mostrare al pubblico quando sia disordinato: Ci sono molte cose buttate sul pavimento..."
The grande vetrata is a backdrop part of Ufficio del Preside. The description is "Una grande vetrata che dà sul giardino. [description of giardino]".
The giardino is a backdrop part of Ufficio del Preside. The description is "Nel giardino non c'è nulla di particolare. Oltre alla siepe c'è la strada: Si vedono i fari di una macchine dietro alla siepe, ma è troppo buio ed è troppo lontana per vedere di più.".
The premi are a plural-named backdrop in Ufficio del Preside. The description is "I soliti premi di competizioni e riconoscimenti scolastici. Nulla di interessante.".
The pavimento is a unmentioned undescribed supporter in Ufficio del Preside.
The foto are a plural-named feminine gender
The scrivania is a feminine gender supporter in Ufficio del Preside. The description is "È [a scrivania] apparentemente molto disordinata."
The scartoffie are a plural-named feminine gender fixed in place thing on scrivania.
[TODO with sup -> "era appiccicata"]
A nota is a feminine gender undescribed thing on the scrivania. The description is "[The noun] è un foglietto giallo appiccicato in un angolino della [scrivania]. C'è scritto: [paragraph break]«ATTENZIONE! Se [the computer] non funziona prova a premere il tasto di accensione. Se anche così non funziona chiama Rausa! Se Rausa non funziona, in quest'ordine: La scuola verrà autodistrutta; Gli alieni ci invaderanno e in aggiunta, cosa ancora più sconvolgente, bisognerà formattare XP e metterci finalmente Linux.»[paragraph break]La nota è firmata da un certo Ivan.".
The computer is a device on scrivania. The description of the computer is "[if noun is switched off][The noun] ha 3 monitor.[otherwise][The noun] non è protetto da alcuna password. In ogni caso pare che non ci sia niente di interessante che salti all'occhio dall'account del Preside. Lo sfondo del [noun] è un'immagine di un orso. Pare che qui tutto sia stato cancellato. [end if]". The indefinite article is "un".
The libreria is a feminine gender supporter in Ufficio del preside. The description is "Ci sono molte foto fra il preside e la sua famigliuola. Su ogni ripiano si vedono decine di pupazzetti a forma di [orsetto]! Mah..".
The orsetto is a thing on libreria. The description of orsetto is "È un innocuo [orsetto] di peluche...".
A tessera is a feminine gender undescribed tessera fotocopie on the libreria. The description of tessera is "Ogni docente usa [a tessera] come questa per fare fotocopie. Questa è firmata dal preside!". Before taking tessera: say "Potrei cacciarmi nei casini prendendola... Ma data la situazione non vedo quale sia il problema.". After taking tessera: say "Presa."
The porta blindata is east of Corridoio presidenza and west of Ufficio del preside. It is a feminine gender porta a tentativi. The description is "[if locked]C'è un pass-card e tastierino numerico che permette di sbloccare [the porta blindata].[otherwise][the porta blindata] è sbloccata.[end if]".
Corridoio presidenza is a room. North of Corridoio presidenza is Presidenza.
The tavolo is a supporter in Corridoio presidenza. The description is "Un lungo tavolo in legno. Sopra vi è una specie di [statuetta].".
The statuetta is a fixed in place thing on tavolo. The description is "Una inutile statuetta .".
The cestino is a container in Corridoio presidenza. The description is "Apparentemente sembra vuoto.".
The badge is an undescribed thing in the cestino. It unlocks the porta blindata. The description is "Si tratta di una scheda magnetica.".
The cicles masticato is a undescribed edible thing in the cestino.
After eating cicles masticato: say "Non credo sia una buona idea, in ogni caso proviamoci.[paragraph break]Ad un primo assaggio direi che l'ultima cosa a cui assomiglia è un ci...[paragraph break][italic type]*click*[line break]* BOOOM *[roman type][paragraph break]...[line break]...[line break]...[paragraph break][italic type](Il mattino seguente)[paragraph break]«Una terribile vicenda è avvenuta questa notte in un istituto scolastico limitrofo a Corso San Maurizio dove un giovane studente è stato ritrovato morto. Da fonti provenienti dal capo della polizia pare che il ragazzo si sia intenzionalmente tolto la vita facendosi esplodere tramite dinamiche ancora da chiarire, scegliendo la sua scuola come ultimo luogo prima di compiere questo suo ultimo folle gesto. Dal diario che gli apparteneva, dicono le autorità, la situazione è apparsa subito chiara: Dai problemi scolastici a quelli familiari e sentimentali il ragazzo aveva deciso la notte prima di entrare di nascosto la notte nell'Istituto e di farsi esplodere. Il riconoscimento del ragazzo è stato un lavoro molto arduo compiuto dalle autorità competenti con l'aiuto dei familiari della vittima. In attesa di aggiornamenti vi terremo aggiornati.»[line break]~ TG News della mattina"; end the story saying "Sei stato disintegrato.".
Part 5 - Lo Scantinato
Scantinato is a dark room. The description is "[if unvisited]Questa probabilmente è la parte meno conosciuta di tutta la scuola. [end if]Si tratta di un luogo molto buio e parecchio umido.[if unvisited] Per me è un vero e proprio 'passaggio segreto'. Solitamente [the Scantinato] è chiuso da [a nastro da cantiere] ed è per questo che pochi sanno che questo posto esista.[end if][if unvisited] Io lo conosco perchè in seconda, per scommessa, l'ho 'visitato' più volte. [the Scantinato] è il luogo perfetto per nascondersi (se non si ha paura del buio..).[end if][if unvisited][paragraph break](Per fortuna ho con me [the mini torcia]!)[end if]".
The scale dello scantinato is up of Scantinato and down of Corridoio presidenza. They are a plural-named feminine gender closed scala. The description is "[if scale dello scantinato is closed]Ora non si può nè salire nè scendere: c'è [a nastro da cantiere] che blocca [the scale dello scantinato].[else][the scale dello scantinato] sono accessibili.[end if]". The printed name is "scale".
Instead of opening scale dello scantinato:
Try examining noun.
Instead of entering inaccessibile scale dello scantinato:
now nastro da cantiere is described;
say "[description of scale dello scantinato]".
Player is in Scantinato.
The nastro da cantiere is an undescribed nastro in Scantinato. The description is "[if noun is tagliato]Sono frammenti di [a noun] sparsi un po['] ovunque.[else]Si tratta di [a noun] rosso.[end if][if scale dello scantinato is inaccessibile] Bisognerebbe rimuoverlo in qualche modo perchè sta intralciando [the scale dello scantinato].[end if]".
Before examining or cutting or taking or attacking nastro da cantiere: now nastro da cantiere is described.
Before examining scale dello scantinato: now nastro da cantiere is described.
Instead of cutting or attacking nastro da cantiere:
if noun is tagliato:
say "Ancora?";
else if scale dello scantinato is accessibile:
say "Sfogarsi su [a noun] non ha prezzo. E a mani nude!";
otherwise:
Now scale dello scantinato is accessibile;
Now nastro da cantiere is tagliato;
say "[The noun] si è strappato a mani nude.".
After taking nastro da cantiere:
Now nastro da cantiere is described;
Now scale dello scantinato is open;
if noun is tagliato:
say "Bene! In questo modo si nascondono anche le prove del mio passaggio...";
otherwise:
say "Preso.".
East of Corridoio scantinato is Scantinato. Corridoio scantinato is a dark room. The description is "[if unvisited]Questa probabilmente è la parte meno conosciuta di tutta la scuola. [end if][The Corridoio scantinato] è buio e molto umido. Ci sono molte [ragnatele]."
The ragnatele are a plural-named feminine gender backdrop part of Corridoio scantinato. The description is "Sebbene questo sia un luogo abbandonato da tutti per fortuna [the ragnatele] sono strappate."
Sala pesi is a dark room. The description is "Vi sono un mucchio di pesi e di attrezzi ginnici.".
The peso 10KG is a thing in Sala pesi. The description is "E dire che è il più leggero che è possibile trovare qui dentro.".
The pesi grandi are a plural-named backdrop. They are part of Sala pesi.
The attrezzi ginnici are a plural-named backdrop. They are part of Sala pesi.
Instead of taking pesi:
say "Assolutamente non posso! Questi sono troppo pesanti!".
The porta antincendio is south of the Sala pesi and north of Corridoio scantinato. Porta antincendio is a feminine gender locked door. The description is "Questo tipo di porte si apre soltanto da un lato e ora come ora [if noun is locked]non[end if] è possibile aprirla.".
Before opening porta antincendio when player is in Sala pesi:
Now Sala pesi is unlocked.
The porta murata sud is south of Corridoio scantinato. It is a feminine gender porta murata. The description is "C'è uno spiraglio fra i mattoni.".
The porta murata sud 1 is south of Scantinato. It is a feminine gender porta murata. The printed name is "porta murata". The description is "C'è uno spiraglio fra i mattoni.".
The spiraglio is a backdrop part of porta murata sud. The description is "È uno spiraglio molto stretto e non è posibile vedere granchè. Ciò nonostante potrei giurare di sentire come un sospiro aldilà di questa parete...[paragraph break][italic type]«C'è n-nessuno?»[line break]...[line break]Nessuna risposta.[paragraph break][roman type]Probabilmente la paura del buio mi sta giocando brutti scherzi..".
The spiraglio 1 is a backdrop part of porta murata sud 1. The description is "È uno spiraglio molto stretto e non è possibile vedere granchè. Tuttavia appare e scompare una flebile luce rossa..".
Part 6 - Primo piano
The Bar is a room. The description is "Tutti i panini sono ritirati nella cucina.".
The registratore di cassa is in Bar. It is a locked closed container. Instead attacking registratore di cassa: say "Con tutta la buona volontà non sarei mai in grado di aprire quest'affare... Servirebbe qualcosa". The peso 5KG unlocks it.
The Cucina is west of Bar. The Cucina is a room.
The ascensore sud is up of Corridoio scantinato and down of bar. It is an ascensore. The printed name is "ascensore".